Phoenix BIOS Developer Blog

HOW-TO: Use UUIDGEN To Generate C-Style GUIDs

Ok, I'm probably the last UEFI programmer to figure this out, but you can use UUIDGEN (which comes with Visual Studio) to generate C-style GUIDs. Just type:

uuidgen -s

and you'll get something like:

INTERFACENAME = { /* 6e43ed89-a0eb-49df-91c6-75e7874b8834 */
    0x6e43ed89,
    0xa0eb,
    0x49df,
    {0x91, 0xc6, 0x75, 0xe7, 0x87, 0x4b, 0x88, 0x34}
  };

Just replace INTERFACE name with your GUID name, remove the trailing ';' and beautify it  a bit and you get:

#define MY_GUID \
  {0x6e43ed89, 0xa0eb, 0x49df, \
  {0x91, 0xc6, 0x75, 0xe7, 0x87, 0x4b, 0x88, 0x34}} 

No magic. And, of course, don't forget uuidgen -n 256 to generate a lot of GUIDs.

HOW-TO: Change directory to source directory for a specific .EFI file.

Many times you will see a file name, such as SystemGraphicsConsoleDxe.efi. The "SystemGraphicsConsoleDxe" portion of that comes from the BASE_NAME keyword in the INF files. The following little batch file will change the directory wherever the INF is located that contains that BASE_NAME in SecureCore Tiano™. This relies on the environment being set up correctly, as described in SU.BAT.

@IF NOT "%1" == "" GOTO STEP0
@echo.
@echo Usage:
@echo   basename base-name
@echo.
@echo Options:
@echo   base-name       Base name (as specified in the module .INF).
@echo.
@echo Description:
@echo   This script changes the current directory to the directory which
@echo   contains the INF where BASE_NAME = base-name for the current project.
@echo.
@echo   The current project must already be set using su.bat
@goto exit

:STEP0
@IF NOT "%PROJECTTIP%"=="" GOTO STEP1
@echo Project not set. Please select a project tip using SU <project-name> <project-version>.
goto exit

:STEP1
@IF EXIST "%PROJECTTIP%\temp\module.list" GOTO STEP2
@echo Project %PROJECTTIP% not built.
goto exit

:STEP2
@FOR /F "tokens=1,2" %%G IN (%PROJECTTIP%\temp\module.list) DO @IF "%%G"=="%1" cd %%~pH && exit /b 0

:exit

HOW-TO: Change directory to a specific INF for SecureCore Tiano™ 2.0

Once you have used su.bat (from the previous article), you can use this one to change to the directory that contains a specific INF file. It uses one of the files output by the build process.

inf inf-file-name

Here is the text for the batch file. It assumes that su.bat has already been used.

@IF NOT "%1" == "" GOTO STEP0
@echo.
@echo Usage:
@echo   inf inf-base-name
@echo.
@echo Options:
@echo   inf-base-name    Name of the INF file in the current project without .INF
@echo.
@echo Description:
@echo   This script changes the current directory to the directory which
@echo   contains the specified INF file for the current project.
@echo.
@echo   The current project must already be set using su.bat
@goto exit

:STEP0
@IF NOT "%PROJECTTIP%"=="" GOTO STEP1
@echo Project not set. Please select a project tip using SU <project-name> <project-version>.
goto exit

:STEP1
@IF EXIST "%PROJECTTIP%\temp\module.list" GOTO STEP2

@echo Project %PROJECTTIP% not built.
goto exit

:STEP2
@FOR /F "tokens=1,2" %%G IN (%PROJECTTIP%\temp\module.list) DO @IF "%%~nH"=="%1" cd %%~pH

:exit

[Updated to add help information]

HOW-TO: Set Up Your SecureCore Tiano™ 2.0 Build Environment

Here's a handy little batch file to set up your build environment for a specific project that I use. It is also the basis for several other useful batch files I will introduce later. It assumes that Visual Studio 2005 or Visual Studio 2008 are already in your build path and the ASL compiler is in C:\ASL.

Just go to the root directory of your SecureCore Tiano™ 2.0 source code and type:

su <project-name> [<project-version>]

If you just type 'su', it will list all projects available. If you type 'su' and a project name and there is only a single version, that will automatically be selected. If there is more than one version available, then the possible versions will be listed.

The batch file sets up two environment variables: PROJECTROOT (which is the root directory of the code) and PROJECTTIP (which is the build directory).

@if not "%1" == "" goto projectroot
@echo.
@echo Usage:
@echo   su project-name [project-version]
@echo.
@echo Options:
@echo   project-name     Name of the SecureCore Tiano(TM) project.
@echo   project-version  Version of the SecureCore Tiano(TM) project. Must be
@echo                    three numeric digits. If not specified, then 000 will
@echo                    be assumed.
@echo.
@echo Description:
@echo   This script sets up the key environment variables for building a project
@echo   for SecureCore Tiano(TM) 2.0.
@echo.
@echo   Select project-name from one of the following:
@dir /b Projects
@goto end

:projectroot
@if not "%PROJECTROOT%" == "" goto projectrev
@set PROJECTROOT=%CD%
@path=%PROJECTROOT%\tools;%path%

:projectrev
@set PROJECTTIPREV=%2
@if not "%PROJECTTIPREV%" == "" goto project
@if not exist "%PROJECTROOT%\Projects\%1\001\project.def" goto defaultprojectrev
@echo More than one project revision present at %PROJECTROOT%\Projects\%1.
@echo Please choose with su %1 xxx (where xxx is the revision) from the following:
@dir /b %PROJECTROOT%\Projects\%1
@goto end

:defaultprojectrev
@set PROJECTTIPREV=000

:project
@if exist "%PROJECTROOT%\Projects\%1\%PROJECTTIPREV%\project.def" goto projecttip
@echo Could not find project file at %PROJECTROOT%\Projects\%1\%PROJECTTIPREV%.
@goto end

:projecttip
@set PROJECTTIP=%PROJECTROOT%\Projects\%1\%PROJECTTIPREV%

:end

HOW-TO: Add a raw binary file to your BIOS (Part 1)

Ever wonder how to get a raw binary file into your SecureCore Tiano™ so that there is just the file header, followed by your data? Well, create a new directory for your binary component. Copy your binary file there. Then create an INF file like the one below. Add the directory and file name of the INF into your DSC file.

If your want to have a binary file that has no header at all, it cannot sit in a firmware volume and must be using a different technique. Next time...

Tim

[defines]
  BASE_NAME = YourBinaryFile
  FILE_GUID = a5f54b78-64e6-40a2-88d2-1d941094c46e
  COMPONENT_TYPE = CONFIG
  FFS_EXT = .raw

#  The sources.common section below provides a list of source files to
#  be included in the MAKEFILE generated by ProcessDsc for this component.

[sources.common]
  $(BUILD_DIR)\YourBinaryFile.bin

[nmake.common]

 

HOW-TO: Decipher #include directory problems.

Having a problem with an #include file, but can’t tell where the error is coming from. Here’s what to do:

In the INF file for your component, go to [nmake.common] and add:

C_FLAGS = $(C_FLAGS) /showIncludes

Make sure you add a # BUGBUG so that you remember to come back and remove it later before you release!

 

SecureCore Tiano(TM) 2.0.